feat: add `awesome-git` & `picom-git`

6 files changed, 207 insertions, 0 deletions

diff --git a/awesome-git/.SRCINFO b/awesome-git/.SRCINFO
new file mode 100644
index 0000000..85dfb7e
--- /dev/null
+++ b/awesome-git/.SRCINFO
@@ -0,0 +1,41 @@
+pkgbase = awesome-git
+	pkgdesc = Highly configurable framework window manager
+	pkgver = 4.3.1347.ga1f58ab97
+	pkgrel = 1
+	url = http://awesome.naquadah.org/
+	arch = i686
+	arch = x86_64
+	license = GPL2
+	makedepends = asciidoctor
+	makedepends = cmake
+	makedepends = docbook-xsl
+	makedepends = git
+	makedepends = imagemagick
+	makedepends = ldoc
+	makedepends = xmlto
+	depends = cairo
+	depends = dbus
+	depends = gdk-pixbuf2
+	depends = libxdg-basedir
+	depends = libxkbcommon-x11
+	depends = lua
+	depends = lua-lgi
+	depends = pango
+	depends = startup-notification
+	depends = xcb-util-cursor
+	depends = xcb-util-keysyms
+	depends = xcb-util-wm
+	depends = xcb-util-xrm
+	depends = libxfixes
+	optdepends = rlwrap: readline support for awesome-client
+	optdepends = dex: autostart your desktop files
+	optdepends = xcb-util-errors: for pretty-printing of X11 errors
+	optdepends = librsvg: for displaying SVG files without scaling artifacts
+	provides = notification-daemon
+	provides = awesome
+	conflicts = awesome
+	backup = etc/xdg/awesome/rc.lua
+	source = awesome-git::git+https://github.com/awesomeWM/awesome.git
+	md5sums = SKIP
+
+pkgname = awesome-git
diff --git a/awesome-git/.gitignore b/awesome-git/.gitignore
new file mode 100644
index 0000000..a6d823a
--- /dev/null
+++ b/awesome-git/.gitignore
@@ -0,0 +1,5 @@
+pkg/
+src/
+*.tar.*
+*.pkg.*
+awesome-git/
diff --git a/awesome-git/PKGBUILD b/awesome-git/PKGBUILD
new file mode 100644
index 0000000..d2a2b9c
--- /dev/null
+++ b/awesome-git/PKGBUILD
@@ -0,0 +1,60 @@
+# Maintainer: Oleg Shparber <trollixx+aur@gmail.com>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
+# Contributor: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Sébastien Luttringer
+# Contributor: xduugu
+# Contributor: Ronald van Haren <ronald.archlinux.org>
+# Contributor: Vesa Kaihlavirta
+# URL: https://github.com/trollixx/aur-packages
+# Upstream: https://projects.archlinux.org/svntogit/community.git/tree/trunk?h=packages/awesome
+
+_pkgname=awesome
+pkgname=${_pkgname}-git
+pkgver=4.3.1655.gad0290bc
+pkgrel=1
+pkgdesc='Highly configurable framework window manager'
+arch=('i686' 'x86_64')
+url='http://awesome.naquadah.org/'
+license=('GPL2')
+depends=('cairo' 'dbus' 'gdk-pixbuf2' 'libxdg-basedir' 'libxkbcommon-x11'
+         'lua' 'lua-lgi' 'pango' 'startup-notification' 'xcb-util-cursor'
+         'xcb-util-keysyms' 'xcb-util-wm' 'xcb-util-xrm' 'libxfixes')
+makedepends=('asciidoctor' 'cmake' 'docbook-xsl' 'git' 'imagemagick' 'ldoc'
+             'xmlto')
+optdepends=('rlwrap: readline support for awesome-client'
+            'dex: autostart your desktop files'
+            'xcb-util-errors: for pretty-printing of X11 errors'
+            'librsvg: for displaying SVG files without scaling artifacts'
+)
+provides=('notification-daemon' 'awesome')
+conflicts=('awesome')
+backup=('etc/xdg/awesome/rc.lua')
+source=("$pkgname::git+https://github.com/kj-sh604/awesome.git")
+md5sums=('SKIP')
+_LUA_VER=5.4
+
+pkgver() {
+  cd $pkgname
+  git describe | sed 's/^v//;s/-/./g'
+}
+
+build() {
+  mkdir -p build
+  cd build
+  cmake ../$pkgname \
+    -DCMAKE_BUILD_TYPE=RELEASE \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DSYSCONFDIR=/etc \
+    -DLUA_INCLUDE_DIR=/usr/include/lua${_LUA_VER} \
+    -DLUA_LIBRARY=/usr/lib/liblua.so.${_LUA_VER} \
+    -DLUA_EXECUTABLE=/usr/bin/lua${_LUA_VER}
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  install -Dm644 "$srcdir"/$pkgname/awesome.desktop \
+    "$pkgdir/usr/share/xsessions/awesome.desktop"
+}
diff --git a/picom-git/.SRCINFO b/picom-git/.SRCINFO
new file mode 100644
index 0000000..ac037cb
--- /dev/null
+++ b/picom-git/.SRCINFO
@@ -0,0 +1,46 @@
+pkgbase = picom-git
+	pkgdesc = X compositor (fork of compton) (git-version)
+	pkgver = 2189_11.172.gcc8e0a98_2024.02.29
+	pkgrel = 1
+	url = https://github.com/yshui/picom
+	arch = i686
+	arch = x86_64
+	license = MIT
+	license = MPL-2.0
+	makedepends = asciidoc
+	makedepends = cmake
+	makedepends = git
+	makedepends = libglvnd
+	makedepends = mesa
+	makedepends = meson
+	makedepends = uthash
+	makedepends = xorgproto
+	depends = hicolor-icon-theme
+	depends = libconfig
+	depends = libdbus
+	depends = libepoxy
+	depends = libev
+	depends = libgl
+	depends = libx11
+	depends = libxcb
+	depends = libxext
+	depends = pcre2
+	depends = pixman
+	depends = xcb-util
+	depends = xcb-util-image
+	depends = xcb-util-renderutil
+	optdepends = dbus: To control picom via D-Bus
+	optdepends = python: For picom-convgen.py
+	optdepends = xorg-xwininfo: For picom-trans
+	optdepends = xorg-xprop: For picom-trans
+	provides = compton
+	provides = compton-git
+	provides = picom
+	conflicts = compton
+	conflicts = compton-git
+	conflicts = picom
+	replaces = compton-git
+	source = git+https://github.com/yshui/picom.git#branch=next
+	md5sums = SKIP
+
+pkgname = picom-git
diff --git a/picom-git/.gitignore b/picom-git/.gitignore
new file mode 100644
index 0000000..fd331c9
--- /dev/null
+++ b/picom-git/.gitignore
@@ -0,0 +1,5 @@
+pkg/
+src/
+*.tar.*
+*.pkg.*
+picom/
diff --git a/picom-git/PKGBUILD b/picom-git/PKGBUILD
new file mode 100644
index 0000000..6bf8f1e
--- /dev/null
+++ b/picom-git/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
+# Contributor: OK100 <ok100 at lavabit dot com>
+# Contributor: Valère Monseur <valere dot monseur at ymail dot com>
+
+pkgname=picom-git
+_gitname=picom
+pkgver=2514_11.497.g2dc2188_2024.07.05
+pkgrel=1
+pkgdesc="X compositor (fork of compton) (git-version)"
+arch=(i686 x86_64)
+url="https://github.com/kj-sh604/${_gitname}"
+license=('MIT' 'MPL-2.0')
+depends=('hicolor-icon-theme' 'libconfig' 'libdbus' 'libepoxy' 'libev' 'libgl' 'libx11'
+         'libxcb' 'libxext' 'pcre2' 'pixman' 'xcb-util' 'xcb-util-image' 'xcb-util-renderutil')
+makedepends=('asciidoc' 'cmake' 'git' 'libglvnd' 'mesa' 'meson' 'uthash' 'xorgproto')
+optdepends=('dbus:          To control picom via D-Bus'
+            'python:        For picom-convgen.py'
+            'xorg-xwininfo: For picom-trans'
+            'xorg-xprop:    For picom-trans')
+provides=('compton' 'compton-git' 'picom')
+conflicts=('compton' 'compton-git' 'picom')
+replaces=('compton-git')
+source=(git+"https://github.com/kj-sh604/${_gitname}.git#branch=next")
+md5sums=("SKIP")
+
+pkgver() {
+    cd ${_gitname}
+    _tag=$(git describe --tags | sed 's:^v::') # tag is mobile, and switches between numbers and letters, can't use it for versioning
+    _commits=$(git rev-list --count HEAD) # total commits is the most sane way of getting incremental pkgver
+    _date=$(git log -1 --date=short --pretty=format:%cd)
+    printf "%s_%s_%s\n" "${_commits}" "${_tag}" "${_date}" | sed 's/-/./g'
+}
+
+build() {
+  cd "${srcdir}/${_gitname}"
+  meson --buildtype=release . build --prefix=/usr -Dwith_docs=true
+  ninja -C build
+}
+
+package() {
+  cd "${srcdir}/${_gitname}"
+
+  DESTDIR="${pkgdir}" ninja -C build install
+
+  # install license
+  install -D -m644 "LICENSES/MIT" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-MIT"
+
+  # example conf
+  install -D -m644 "picom.sample.conf" "${pkgdir}/etc/xdg/picom.conf.example"
+}